;;
;; GGRTF::Misc - TinyFugue module for miscellaneous extensions @ BatMUD
;; (C) Copyright 2004-2005 Ggr Pupunen
;;
;; This file (triggerset) is Free Software distributed under
;; GNU General Public License version 2.
;;
;; NOTICE! This file requires GGRTF (version 0.5.0 or later) to be loaded.
;;
/deftoggle -n"rmisc" -d"Miscellaneous reporting"
/set opt_rmisc=on

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Consider reporting
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
/def -i -mregexp -t"^You take a close look at (.*) in comparison to yourself.$" consider0 =\
	/set conexp=%;/set conopp=%;/set conname=%{P1}

/def -i -mregexp -t"^You would get (.*) experience for" consider1 =\
	/set conexp=%{P1}

/def -i -mregexp -t"^The final estimation is that (.*)" consider2 =\
	/set conval=%{P1}%;\
	/if (regmatch("doesn't look very dangerous", {conval})) /set conopp=dlvd%;\
	/elseif (regmatch("fair opponent.", {conval})) /set conopp=fair%;\
	/elseif (regmatch("nearly equal in power.", {conval})) /set conopp=equal%;\
	/elseif (regmatch("quite skilled, beware.", {conval})) /set conopp=skilled%;\
	/elseif (regmatch("much stronger than you, beware.", {conval})) /set conopp=much stronger%;\
	/elseif (regmatch("has such bulging muscles that your hands tremble.", {conval})) /set conopp=DANGEROUS%;\
	/endif%;\
	/if (({conexp}!~"") & ({conopp}!~"")) /msr %{conname}: %{conexp} exp, %{conopp}%;\
	/elseif ({conexp}!~"") /msr %{conname}: %{conexp} exp%;\
	/elseif ({conopp}!~"") /msr %{conname}: %{conopp}%;/endif


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Some special hilites and miscellaneous
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Highlite plants and mineral deposits
/def -i -p9999 -F -aCgreen -mregexp -t"(plant stands|plant lies|growing|grows here|is starting to grow|tree stands|bush is here|oak tree)" lite_plant1
/def -i -p9999 -F -aCyellow -mregexp -t"in the ground" lite_mineral1

/def -i -p9999 -F -aCgreen -mregexp -t"^You feel like you just got slightly better in (.*)$" misc_improved = /mse improved in %{P1}

/def -i -p9999 -F -msimple -t"Your disc wavers dangerously." misc_fdweak = /msr Disc falling!
/def -i -p9999 -F -msimple -t"You reload magical energy to the disc that is floating in the air." misc_fdreload = /msr Disc reloaded.


;; Ambush
/def -i -p9999 -F -aCred -msimple -t"You cannot leave, you have been AMBUSHED." rec_ambush1 =\
	/if ({opt_rmisc}=~"on") /msr AMBUSHED!%;/endif

;; Uncon
/def -i -p9999 -F -ag -mregexp -t"^([A-Z][A-Za-z]+) lapses into unconsciousness from severe loss of blood.$" rec_uncon =\
	/msq @{BCred}!!!@{n} @{BCwhite}%{P1}@{n} is @{BCgreen}UNCON@{n} @{BCred}!!!@{n}%;\
	/if ({opt_rmisc}=~"on") /msr %{P1} is UNCON!%;/endif

;; Uncon
/def -i -p9999 -F -ag -mregexp -t"^([A-Z][a-z]+) is now in the 1st row.$" rec_firstrow =\
	/msq @{BCred}!!!@{n} @{BCwhite}%{P1}@{n} @{BCyellow}is now in 1st row@{n} @{BCred}!!!@{n}%;\
	/if ({opt_rmisc}=~"on" & {P1}=~{set_plrname}) /msr %{P1} is now in 1st row!%;/endif


;; Multicolored Demons (event)
/def -i -aCred -msimple -t"A Nasty Multicolored Demon arrives with puff of red smoke." rec_mcdemon =\
	/msr Multicolored Demon! (MCDemons event)


;; Warn about invis tells and emotes
/def -i -p9999 -F -aCgreen -mregexp -t"^You tell ([^']*)" rec_tell =\
/if ({opt_rmisc}=~"on" & {prot_invis} > 0 & !regmatch("(monster)", {P1}))\
	/msq WARNING! You are using 'tell' while INVISIBLE!%;\
	/endif

/def -i -p9999 -F -aCgreen -mregexp -t"^You emote to " rec_emote =\
/if ({opt_rmisc}=~"on" & {prot_invis} > 0)\
	/msq WARNING! You are using 'emote' while INVISIBLE!%;\
	/endif

/def -i -aCred -msimple -t"You fail to start the fire." fb_fail = /skill_fail

/def -i -aBCred -mregexp -t"^Your ([A-Za-z ]+) gets damaged; it's now in ([a-z]+) condition.$" eqdamaged =\
	/msr NOTICE! %{P1} got damaged! (%{P2})

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Miscellaneous resists
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
/def -i -p1 -F -aCred -msimple -t"You are not affected by feeblemind." curse_feeblemind =\
	/msr Resisted feeblemind!


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Camping
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
/def -i -p9999 -F -aCgreen -msimple -t"You lie down and begin to rest for a while." camp_start =\
	/set camp_st=on%;\
	/set camp_hp=%{status_hp}%;\
	/set camp_sp=%{status_sp}%;\
	/set camp_ep=%{status_ep}%;\
	/set camp_time=$[time()]

/def -i -p9999 -F -aCgreen -msimple -t"You awaken from your short rest, and feel slightly better." camp_end =\
	/if ({camp_st}=~"on") \
	/set camp_st=off%;@sc%;\
	/def -p1 -n1 -F -mregexp -t"^H:" camp_awake =\
	/msr Awake - $$[status_hp - camp_hp]hp, $$[status_sp - camp_sp]sp, $$[status_ep - camp_ep]ep $[prgetstime(camp_time)]%;\
	/endif

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Ceremony
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
/set ceremony_st=off

/def -i -p9999 -F -msimple -t"You perform the ceremony." ceremony_on =\
	/if ({skill_st2}=~"on")\
		/set skill_st2=off%;\
		/set ceremony_st=on%;\
		/endif

/def -i -p9999 -F -msimple -t"You have an unusual feeling as you cast the spell." ceremony_off =\
	/set ceremony_st=off

/def ceremony =\
	/if ({ceremony_st}=~"on")\
		/msq Ceremony already in effect!%;\
		/else \
		@@use ceremony%;\
		/endif