;;
;; GgrTF::Spiders - Spider guild support @ BatMUD
;; (C) Copyright 2006 Jutom & Matti Hämäläinen (Ggr)
;;
;; This file (triggerset) is Free Software distributed under
;; GNU General Public License version 2.
;;
;; NOTICE! This file requires GgrTF (version 0.6.0 or later) to be loaded.
;;
/loaded GgrTF::Spiders

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Initialization and options
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
/set spider_t=0
/set spider_drain=0
/set spider_easy=0


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Spider related lites
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Spiderservant
/def -i -F -mregexp -P1Cred;2Cyellow -t'^([a-zA-Z ]+) the spider whispers \'(.*)\'$' gservant_whisper


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Spider demon control
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
/eval /def -i -p9999 -ag -msimple -t"You feed %{set_plrname}'s spider demon's hunger with your ritual." gspider_ctrl =\
	/msq @{BCgreen}Demon controlled.@{n}%%;\
	/set spider_t=$$[time()]%%;\
	/set spider_drain=0

;; Point used or not?
/eval /def -i -p9999 -ag -msimple -t"%{set_plrname}'s demon feels easier to control than usual." gspider_easydrain =\
	/set spider_easy=1

;; Spider demon channelling message
/eval /def -i -p9999 -ag -msimple -t"%{set_plrname}'s spider demon draws power from you." gspider_drains =\
	/if (spider_easy == 1)\
		/msq @{BCgreen}Demon channelled with points.@{n}%%;\
	/else \
		/msq @{BCred}Demon channelled without points!!!@{n}%%;\
	/endif%%;\
	/set spider_drain=$$[spider_drain+1]%%;\
	/set spider_easy=0

;; Channelling with help from queen
/def -i -p9999 -ag -msimple -t"Spider Queen smiles upon you and helps you control the demon." gspider_queendrain =\
	/msq @{BCgreen}Demon battlechannelled.@{n}%;\
	/set spider_drain=$[spider_drain+1]%;\
	/set spider_easy=0

;; List how many drains done
/def spidstatus =\
	/if (spider_t > 0)\
		/msq @{BCyellow}Time since last control:@{n} @{BCwhite}$[prgetstime(spider_t)]@{n}%;\
	/else \
		/msq @{BCred}No demon controls registered yet.@{n}%;\
	/endif%;\
	/if (spider_drain > 0)\
		/msq @{BCgreen}Drains:@{n} @{BCwhite}%{spider_drain}@{n}%;\
	/else \
		/msq @{BCgreen}No drains happened yet!@{n}%;\
	/endif

;; Demon banished
/def -i -p9999 -msimple -t"You feel your mind returning back to normal." gspider_banished =\
	/set spider_drain=0