;;
;; GgrTF::TF5 - TinyFugue 5.x compatibility and extras
;; (C) Copyright 2006 Matti Hämäläinen (Ggr)
;;
;; This file (triggerset) is Free Software distributed under
;; GNU General Public License version 2.
;;
;; NOTICE! This file requires GgrTF (version 0.6.0 or later) to be loaded.
;;
/loaded GgrTF:TF5

/if (!regmatch("5\.[0-9]+", ver()))\
	/gerror This module is designed for TinyFugue v5.0 or later, it does not work in older versions of TF%;\
	/exit%;\
/endif

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; TF5 extended statusline handling
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
/def -i gstatus_add =\
	/eval /status_add -s0 -r$[status_start+{1}] %{2}

/def -i gstatus_add_val =\
	/if (gstatus_tmps!~"")\
		/set gstatus_tmps=%{gstatus_tmps}%%;%;\
	/endif%;\
	/set gstatus_tmps=%{gstatus_tmps}/set status_attr_var_status_%{2}=$$[prgetnlite(status_%{2},status_%{2}max)]%;\
	/status_add -s0 -r$[status_start+{1}] "["%;\
	/status_add -s0 -r$[status_start+{1}] "%{3}:":2:BCwhite%;\
	/status_add -s0 -r$[status_start+{1}] status_%{2}:-5%;\
	/status_add -s0 -r$[status_start+{1}] "/"%;\
	/status_add -s0 -r$[status_start+{1}] status_%{2}max:-5:BCgreen%;\
	/status_add -s0 -r$[status_start+{1}] "]"

/def -i gstatus_add_lightc =\
	/if (gstatus_tmps!~"")\
		/set gstatus_tmps=%{gstatus_tmps}%%;%;\
	/endif%;\
	/set gstatus_tmps=%{gstatus_tmps}/set status_attr_var_light_%{3}=$$[%{4}]%;\
	/set status_var_light_%{3}="%{3}"%;\
	/status_add -s0 -r$[status_start+{1}] light_%{3}:1

/def -i gstatus_add_light =\
	/test gstatus_add_lightc({1},{2},{3},"gstatus_get_val(%{2}_st)")

/def -i gstatus_init =\
	/prdefvar -n"status_height" -v"2" -c"The number of rows in the status area in TF visual mode (GgrTF::TF5 uses 2)"%;\
	/prdefvar -n"status_start" -v"0" -c"Start row used by GgrTF in TF visual mode (GgrTF::TF5 uses 0 by default)"%;\
	/if (status_height < 2) /set status_height=2%;/endif%;\
	/set gstatus_tmps=%;\
	/test gstatus_add(0, "-c")%;\
	/test gstatus_add_val(0, "hp", "H")%;\
	/test gstatus_add_val(0, "sp", "S")%;\
	/test gstatus_add_val(0, "ep", "E")%;\
	/test gstatus_add(0, "\\\"[\\\"")%;\
	/test gstatus_add(0, "prmove_last:2:BCgreen")%;\
	/test gstatus_add_light(0, "ceremony", "C")%;\
	/test gstatus_add_light(0, "spell", "S")%;\
	/test gstatus_add_light(0, "skill", "K")%;\
	/test gstatus_add_lightc(0, "camp", "c", "gstatus_get_camp()")%;\
	/test gstatus_add(0, "\\\"]\\\"")%;\
	/test gstatus_add(1, "-c \\\"[\\\"")%;\
	/test gstatus_add(1, "status_protstr2::Cgreen")%;\
	/test gstatus_add(1, "\\\"]\\\"")%;\
	/def -i gstatus_update = %{gstatus_tmps}%;\
	/unset gstatus_tmps

/gstatus_init
/gstatus_update