###
### Based on example from https://www.qt.io/blog/standalone-boot2qt-/-yocto-sdk-cmake-toolchain
### See also https://doc.qt.io/qt-6/configure-linux-device.html
###
cmake_minimum_required(VERSION 3.11)
include_guard(GLOBAL)

set(QT_BUILD_EXAMPLES OFF)
set(QT_BUILD_TESTS OFF)

set(CMAKE_SYSTEM_NAME Windows)
set(CMAKE_SYSTEM_PROCESSOR x86)
set(MINGW_NAME i686-w64-mingw32)
set(QT_HOST_PATH /usr/lib/x86_64-linux-gnu/cmake/)
set(MINGW_TOOL_PREFIX ${MINGW_NAME}-)

set(CMAKE_C_COMPILER ${MINGW_TOOL_PREFIX}gcc)
set(CMAKE_CXX_COMPILER ${MINGW_TOOL_PREFIX}g++)

set(CMAKE_PREFIX_PATH /usr/${MINGW_NAME})
set(CMAKE_PROGRAM_PATH /usr/${MINGW_NAME}/bin)


set(MINGW_COMPILER_FLAGS "-fstack-protector-strong -D_FORTIFY_SOURCE=2 -Wformat -Wformat-security -Werror=format-security")
set(MINGW_COMPILER_FLAGS_RELEASE "-O2 -pipe -g")
set(MINGW_LINKER_FLAGS "")

set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
set(CMAKE_FIND_ROOT_PATH_MODE_PACKAGE ONLY)


include(CMakeInitializeConfigs)

function(cmake_initialize_per_config_variable _PREFIX _DOCSTRING)
  if (_PREFIX MATCHES "CMAKE_(C|CXX|ASM)_FLAGS")
    set(CMAKE_${CMAKE_MATCH_1}_FLAGS_INIT "${MINGW_COMPILER_FLAGS}")

    foreach (config DEBUG RELEASE MINSIZEREL RELWITHDEBINFO)
      if (DEFINED MINGW_COMPILER_FLAGS_${config})
        set(CMAKE_${CMAKE_MATCH_1}_FLAGS_${config}_INIT "${MINGW_COMPILER_FLAGS_${config}}")
      endif()
    endforeach()
  endif()

  if (_PREFIX MATCHES "CMAKE_(SHARED|MODULE|EXE)_LINKER_FLAGS")
    foreach (config SHARED MODULE EXE)
      set(CMAKE_${config}_LINKER_FLAGS_INIT "${MINGW_LINKER_FLAGS}")
    endforeach()
  endif()

  _cmake_initialize_per_config_variable(${ARGV})
endfunction()