dnl ***
dnl *** Process this file with autoconf to produce a configure script.
dnl ***

dnl Require autoconf 2.54 or later
AC_PREREQ(2.54)

dnl Initialize
AC_INIT(XMMS-SID, 0.8.0beta1, ccr@tnsp.org)
AC_COPYRIGHT([[(C) 2002-2003 Matti 'ccr' Hämäläinen]])
AC_CONFIG_SRCDIR(src/xmms-sid.h)
AM_INIT_AUTOMAKE
AC_CONFIG_HEADERS(config.h)


dnl ***
dnl *** Some general checks
dnl ***
AC_DISABLE_STATIC
AC_LIBTOOL_DLOPEN
AM_PROG_LIBTOOL


dnl ***
dnl *** Checks for programs
dnl ***
AC_PROG_CC
AC_PROG_CXX
dnl AC_PROG_CPP
AC_PROG_INSTALL
AC_HEADER_STDC

AC_PREFIX_PROGRAM(xmms)

dnl ***
dnl *** Checks for generic libraries
dnl ***
AM_PATH_GLIB(1.2.8,,AC_MSG_ERROR([*** GLib >= 1.2.8 not found. You either don't have GLib at all or your GLib is too old. Latest GLib can be found from Gtk+ homepages (http://www.gtk.org/)]))

AM_PATH_GTK(1.2.8,,AC_MSG_ERROR([*** Gtk+ >= 1.2.8 not found. You either don't have Gtk+ at all or your Gtk+ is too old. Latest Gtk+ can be found from Gtk+ homepages (http://www.gtk.org/)]), gthread)


dnl ***
dnl *** libSIDPlay 1 options
dnl ***
AC_ARG_WITH(libsidplay1,
[  --with-libsidplay1=PREFIX   Enable SIDPlay1 with install-PREFIX is],
[
if test "$withval" = yes; then
xs_sidplay1=yes
xs_sidplay1_library=""
xs_sidplay1_includes=""
else
if test "$withval" = no; then
	xs_sidplay1=no
	else
	xs_sidplay1=yes
	xs_sidplay1_includes="$withval/include"
	xs_sidplay1_library="$withval/lib"
	fi
fi
],[
xs_sidplay1=yes
xs_sidplay1_library=""
xs_sidplay1_includes=""
])

AC_ARG_WITH(sidplay1-inc,
[  --with-sidplay1-inc=DIR    Where the SIDPlay1 headers are located],
[xs_sidplay1_includes="$withval"],)

AC_ARG_WITH(sidplay1-lib,
[  --with-sidplay1-lib=DIR    Where the SIDPlay1 library is installed],
[xs_sidplay1_library="$withval"],)


dnl ***
dnl *** libSIDPlay 2 options
dnl ***
AC_ARG_WITH(libsidplay2,
[  --with-libsidplay2=PREFIX   Enable SIDPlay1 with install-PREFIX is],
[
if test "$withval" = yes; then
xs_sidplay2=yes
xs_sidplay2_library=""
xs_sidplay2_includes=""
else
if test "$withval" = no; then
	xs_sidplay2=no
	else
	xs_sidplay2=yes
	xs_sidplay2_includes="$withval/include"
	xs_sidplay2_library="$withval/lib"
	fi
fi
],[
xs_sidplay2=yes
xs_sidplay2_library=""
xs_sidplay2_includes=""
])

AC_ARG_WITH(sidplay2-inc,
[  --with-sidplay2-inc=DIR    Where the SIDPlay2 headers are located],
[xs_sidplay2_includes="$withval"],)

AC_ARG_WITH(sidplay2-lib,
[  --with-sidplay2-lib=DIR    Where the SIDPlay2 library is installed],
[xs_sidplay2_library="$withval"],)


dnl ***
dnl *** Determine if libraries are wanted and available
dnl ***
OPT_SIDPLAY1="no"
if test "$xs_sidplay1" = yes; then
XS_PATH_LIBSIDPLAY1
if test "$xs_have_sidplay1" = yes; then
AC_DEFINE(HAVE_SIDPLAY1)
OPT_SIDPLAY1="yes"
else
AC_MSG_ERROR([libSIDPlay1 library and/or headers were not found!])
fi
fi


OPT_SIDPLAY2="no"
if test "$xs_sidplay2" = yes; then
LIBSIDPLAY2_REQUIRED_VERSION="2.1.0"
XS_PATH_LIBSIDPLAY2
if test "$xs_have_sidplay2" = yes; then
AC_DEFINE(HAVE_SIDPLAY2)
OPT_SIDPLAY2="yes"
BUILDERS_FIND
BUILDERS_FIND_RESID
BUILDERS_FIND_HARDSID
if test "$builders_available" = no; then
AC_MSG_ERROR([No builder modules were found in the sidbuilders directory!]);
fi
else
AC_MSG_ERROR([libSIDPlay2 library and/or headers were not found!])
fi
fi


dnl ***
dnl *** Check if we have some SIDPlay version
dnl ***
if test "$OPT_SIDPLAY1" = no; then
if test "$OPT_SIDPLAY2" = no; then
AC_MSG_ERROR([Either libSIDPlay1 or libSIDPlay2 is required! Please read INSTALL for more information!])
fi
fi


dnl ***
dnl *** Check XMMS version
dnl ***
AM_PATH_XMMS(1.2.0,, [
AC_MSG_ERROR([*** XMMS >= 1.2.0 not found. You need XMMS v1.2.0 or later to use XMMS-SID plugin.])
])
libdir=$XMMS_INPUT_PLUGIN_DIR

XMMS_TEST_VERSION($XMMS_VERSION, 1.2.5, [
AC_DEFINE(HAVE_XMMSEXTRA)
OPT_XMMSEXTRA="yes"
], [
OPT_XMMSEXTRA="no"
])


dnl ***
dnl *** Define some templates
dnl ***
AC_DEFINE(HAVE_XMMSEXTRA, 0, Define to 1 if you have XMMS version 1.2.5 or later)
AC_DEFINE(HAVE_SIDPLAY1, 0, Define to 1 if you want to use libSIDPlay 1)
AC_DEFINE(HAVE_SIDPLAY2, 0, Define to 1 if you want to use libSIDPlay 2)
AC_DEFINE(HAVE_RESID_BUILDER, 0, Define to 1 if you have reSID with libSIDPlay 2)
AC_DEFINE(HAVE_HARDSID_BUILDER, 0, Define to 1 if you have HardSID with libSIDPlay 2)


dnl ***
dnl *** And finally, output the all generatable files!
dnl ***
AC_CONFIG_FILES([
Makefile
src/Makefile
xmms-sid.spec
])
AC_OUTPUT


dnl ***
dnl *** Show the result message
dnl ***
AC_MSG_RESULT([
	XMMS-SID has been configured successfully:

	Installation directory        : $libdir
	XMMS >= v1.2.5 extra features : $OPT_XMMSEXTRA
	libSIDPlay 1 support          : $OPT_SIDPLAY1
	libSIDPlay 2 support          : $OPT_SIDPLAY2

])